高畑ラボ　プレゼンツ

#include "FILE_int2char_char2int_02.hsp
#include "FILE_str2ints_ints2str.hsp

sdim s,32000
notesel s
max="notemax:"+notemax
//	notemax表示用
input max,240,20;ID0

objsize 120,20

pos 0,20
button "SET",*l_set;ID1
pos 0,40
mes "NO."
n=0
pos 30,40
//	SETのNO入力用
input n,90,20;ID2

pos 120,20
button "ADD",*l_add;ID3

pos 240,20
button "GET",*l_get;ID4
pos 240,40
mes "NO."
nn=0
pos 270,40
//	GETのNo入力用
input nn,90,20;ID5
pos 360,20

button "dump",*l_dump;ID6
pos 0,60
t="command?"
//	メッセージ表示用
input t,240,20;ID7
u=""
//	操作mesbox
mesbox u,640,320,5;ID8

pos 480,20
button "source dump",*l_source_dump;ID9
stop

//	noteに文字列を変換してSET
*l_set
if (n>=0)&&(notemax>n){
s_tmp_d=""
//	文字列を数値群に変換
str2ints s_tmp_d,u
//	noteに上書き
noteadd s_tmp_d,n,1
ss="set OK no "+n
//	メッセージ表示用inputboxにメッセージを表示
objprm 7,ss
}else{
//	入力したNOが不正
ss="set NG no "+n
objprm 7,ss
}
stop

//	noteに文字列を変換して追加
*l_add
s_tmp=""
//	文字列を数値群に変換
str2ints s_tmp,u
//	noteに文字列を変換して追加
noteadd s_tmp
ss="add to note."
//	メッセージ表示用inputboxにメッセージを表示
objprm 7,ss
max="notemax:"+notemax
//	notemax表示用inputboxを更新
objprm 0,max
stop

//	noteから文字列を取り出す
*l_get
if (nn>=0)&&(notemax>nn){
s_tmp_e=""
s_tmp_f=""
//	noteから文字列を取得
noteget s_tmp_e,nn
//	数値群を文字列に変換
ints2str s_tmp_f,s_tmp_e
//	操作用mesboxに取得して変換した文字列を表示
objprm 8,s_tmp_f
ss="get OK no "+nn
//	メッセージ表示用inputboxにメッセージを表示
objprm 7,ss
}else{
//	入力したNOが不正
ss="get NG no "+nn
objprm 7,ss
}
stop

//	noteの中身をdump
*l_dump
to_mesbox=""
s_tmp_b=""
s_tmp_c=""
repeat notemax
//	NOを文字列に書き出す
to_mesbox+="NO："+(cnt+1)+"\n"
//	noteから文字列を取得
noteget s_tmp_b,cnt
//	数値群を文字列に変換
ints2str s_tmp_c,s_tmp_b
//	変換した文字列を書き出す
to_mesbox+=""+s_tmp_c+"\n"
loop
//	操作用mesboxに文字列を表示
objprm 8,to_mesbox
ss="dump."
//	メッセージ表示用inputboxにメッセージを表示
objprm 7,ss
stop

//	noteの中身を変換せずにdump
*l_source_dump
to_mesbox=""
s_tmp_b=""
repeat notemax
//	NOを文字列に書き出す
to_mesbox+="NO："+(cnt+1)+"\n"
//	noteから文字列を取得
noteget s_tmp_b,cnt
//	数値群を書き出す
to_mesbox+=""+s_tmp_b+"\n"
loop
//	操作用mesboxに文字列を表示
objprm 8,to_mesbox
ss="sc dump."
//	メッセージ表示用inputboxにメッセージを表示
objprm 7,ss
stop